From 724ac8ae394675a78c2977c6e35555b210256e01 Mon Sep 17 00:00:00 2001
From: Taylan Kammer <taylan.kammer@gmail.com>
Date: Mon, 1 Jun 2026 21:49:37 +0200
Subject: docs -> doc

---
 doc/c1/grammar/zbnf.txt | 77 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 doc/c1/grammar/zbnf.txt

(limited to 'doc/c1/grammar/zbnf.txt')

diff --git a/doc/c1/grammar/zbnf.txt b/doc/c1/grammar/zbnf.txt
new file mode 100644
index 0000000..923ac83
--- /dev/null
+++ b/doc/c1/grammar/zbnf.txt
@@ -0,0 +1,77 @@
+; Custom notation with PEG semantics
+
+Stream        : Unit ( Blank Unit )*
+
+
+Unit          : Blank* [Datum]
+
+Blank         : '\t'...'\r' | SP | Comment
+
+
+Datum         : OneDatum ( [JoinChar] OneDatum )*
+
+JoinChar      : '.' | ':'
+
+
+Comment       : ';' ( SkipUnit | SkipLine )
+
+SkipUnit      : '~' Unit
+
+SkipLine      : ( ~LF )* [LF]
+
+
+OneDatum      : BareString | CladDatum
+
+
+BareString    : SpecBareChar ( BareChar | JoinChar )*
+              | BareChar+
+
+SpecBareChar  : '+' | '-' | JoinChar | DIGIT
+
+BareChar      : ALPHA | DIGIT
+              | '!' | '$' | '%' | '*' | '+' | '-' | '/'
+              | '<' | '=' | '>' | '?' | '^' | '_' | '~'
+
+
+CladDatum     : PipeStr | QuoteStr | HashExpr | QuoteExpr | List
+
+PipeStr       : '|' ( PipeStrChar | '\' StringEsc )* '|'
+QuoteStr      : '"' ( QuotStrChar | '\' StringEsc )* '"'
+HashExpr      : '#' HashExprs
+QuoteExpr     : "'" Datum | '`' Datum | ',' Datum
+List          : ParenList | SquareList | BraceList
+
+
+PipeStrChar   : ~( '|' | '\' )
+QuotStrChar   : ~( '"' | '\' )
+
+StringEsc     : '\' | '|' | '"' | ( HTAB | SP )* LF ( HTAB | SP )*
+              | '0' | 'a' | 'b' | 't' | 'n' | 'v' | 'f' | 'r' | 'e'
+              | 'x' HexByte* ';'
+              | 'u' UnicodeSV ';'
+
+HexByte       : HEXDIG HEXDIG
+UnicodeSV     : HEXDIG+
+
+
+HashExprs     : '!' ( SP | HTAB )* HBangLine [ LF ]
+              | '%' Label ( '%' | '=' Datum )
+              | '\' BareString | CladDatum
+              | Rune [ '\' BareString | CladDatum ]
+
+HBangLine     : HBChars+ ( SP | HTAB )* [ HBChars+ ]
+HBChars       : ~( SP | HTAB | LF )
+Label         : HEXDIG+
+Rune          : ALPHA ( ALPHA | DIGIT )*
+
+
+ParenList     : '(' ListBody ')'
+SquareList    : '[' ListBody ']'
+BraceList     : '{' ListBody '}'
+
+ListBody      : Unit* [ Blank* '&' Unit ] Blank*
+
+
+;; Local Variables:
+;; eval: (flyspell-mode -1)
+;; End:
-- 
cgit v1.2.3